home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh1x
/
sh16a.d64
/
sinus-plot l1
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
951b
|
34 lines
10 REM SINUS-PLOT PROGRAMM
20 V=53248 : REM STARTADRESSE DES GRAPHIK-PROZESSORS
30 AD=8192 : REM STARTADRESSE DER HI-RES BITMAP
40 POKEV+17,59 : REM EINSCHALTEN DER GRAPHIK
50 POKEV+24,24 : REM EINSCHALTEN DER GRAPHIK
60 FOR I=1024 TO 2023
70 : POKE I,16 : REM FARBKENNZAHL
80 NEXT I
90 FOR I=8192 TO 16383 : REM LOESCHEN DER HI-RES BITMAP
100 : POKE I,0
110 NEXT I
120 FOR X=0 TO 319 : REM ZEICHNEN DER X-ACHSE
130 : Y=100 : REM POSITION DER X-ACHSE
140 : GOSUB 1000 : REM AUFRUF DER ZEICHENROUTINE
150 NEXT X
160 FOR Y=0 TO 199 : REM ZEICHNEN DER Y-ACHSE
170 : X=160 : REM POSITION DER Y-ACHSE
180 : GOSUB 1000 : REM AUFRUF DER ZEICHEN-ROUTINE
190 NEXT Y
200 X=0
210 FOR I=-3.141593 TO 3.141593 STEP 0.019635
220 : REM INTERVALLGRENZEN
230 : Y=100+99*SIN(I) : REM FUNKTION
240 : GOSUB 1000
250 : X=X+1
260 NEXT I
270 GOTO 270 : REM DAMIT DER BILDSCHIRM NICHT VERAENDERT WIRD
1000 OY=320*INT(Y/8)+(Y AND 7) : REM BERECHNRN DES PUNKTES
1010 OX=8*INT(X/8)
1020 MA=2^((7-X) AND 7)
1030 AV=AD+OY+OX
1040 POKE AV,PEEK(AV) OR MA : REM PLOTTEN DES PUNKTES
1050 RETURN